מאקרו לוורד לבחירת כל המילה כולל תווי פיסוק

[מעלה ומוריד]

בוורד, כאשר משתמשים בCtrl+Shift+Left/Right לבחירת המילה הבאה הבחירה נעצרת בתוי הפיסוק כגון " או ( או ,
ברוב השימושים של בחירה זו נצרכת בחירת כל המילה עד לתו הרווח
לעיתים קרובות כאשר בתוך הטקסט יש ציונים כגון (ל"א, ב') התענוג מושלם
ניסיתי מכמה כיוונים ליצור מאקרו שיבחר את כל התווים מהמקום שבו הסמן עומד עד לתו הרווח, ונכשלתי במטרה זו
אם יהיה לי כזה מאקרו, אקצה אותו לCtrl+Shift+Left/Right ולישראל יהיה טוב מאד
אני לא רוצה להטריח אף אחד בשביל הנוחות שלי, אמנם האמת היא שסביר להניח שיש בזה תועלת גדולה דרבים
אודה מאד לכל עזרה!

ChatGPT הביא לי את המאקרו הבא, שכמובן לא נותן את התוצאה, אלא עוצר מיד אחרי התו הראשון
אני מביא את זה כאן למקרה שזה באמת התחלה ויקל על המסייעים

Sub CheckForSpaces()
    Dim currentChar As String
    Dim i As Integer
    
    For i = 1 To Len(Selection.Text)
        currentChar = Mid(Selection.Text, i, 1)
        If currentChar = " " Then
            Exit For
        Else
            Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
        End If
    Next i
End Sub

[שלום עולם 0]

לא מבין איפה זה כ"כ עוזר (תמיד אפשר ללחוץ שוב ולקבל את המילה הבאה בשלמותה), עכ"פ הקוד הזה עשוי לעזור

Sub SelectToNextSpace()
    Dim sel As Range
    Set sel = Selection.Range
    sel.MoveEndUntil " ", wdForward
    sel.Select
End Sub

[מעלה ומוריד]

@שלום-עולם-0 כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

לא מבין איפה זה כ"כ עוזר (תמיד אפשר ללחוץ שוב ולקבל את המילה הבאה בשלמותה), עכ"פ הקוד הזה עשוי לעזור

תודה שהשקעת גם בלי להבין!...

לגבי הקוד, אני צריך משהו שיחליף את Ctrl+Shift+left, הקוד שלך אכן בוחר את המילה בשלימותה, אבל הפעלה חוזרת של המאקרו לא בוחרת את המילה הבאה

[yossiz]

Sub SelectToNextSpace()
    Dim sel As Range
    Set sel = Selection.Range
    sel.MoveEnd 1
    While sel.Characters.Last = " "
        sel.MoveEnd 1
    Wend
    sel.MoveEndUntil " ", wdForward
    sel.Select
End Sub

[מעלה ומוריד]

@yossiz תודה רבה!
איזו הקלה...
האם תוכל להתאים מאקרו זה גם לבחירה מהסוף להתחלה? (Ctrl+Shift+right)

[yossiz]

Const whiteSpace As String = " " & vbTab & vbCrLf

Sub SelectToNextWhiteSpaceForward()
    Selection.MoveEndWhile whiteSpace, wdForward
    Selection.MoveEndUntil whiteSpace, wdForward
End Sub

Sub SelectToNextWhiteSpaceBackward()
    Selection.MoveStartWhile whiteSpace, wdBackward
    Selection.MoveStartUntil whiteSpace, wdBackward
End Sub

[מעלה ומוריד]

@yossiz יש דרך לערוך את הפקודות המובנות בוורד?
למה אני שואל? כי אני רוצה בעצמי קצת לעשות משהו.
מה שהגדרתי עכשיו הוא ש Ctrl+Shift+Left/Right מבצעים את המאקרו שצירפת
אולם במצב הרגיל של וורד כאשר Ctrl+Shift+Left מבצע את הפקודה WordLeftExtend ובוחר נניח 3 מילים, ואז אני עושה Ctrl+Shift+Right הוא מוריד מילה אחת מהבחירה, ואילו כעת הוא פשוט בוחר עוד מילה מימין לטקסט המסומן...
(הובנתי?) לכן הייתי רוצה לראות את קוד הפקודה WordLeftExtend ולראות את השורה שאחראית על כך שבמצב בחירה הקיצור Ctrl+Shift+Right לא מפעיל את הפקודה WordLeftExtend אלא מוריד מילה מהבחירה (אם באמת יש שם שורה כזו...)

[yossiz]

@מעלה-ומוריד כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

(אם באמת יש שם שורה כזו...)

יש שורה (או כמה שורות) שמטפלים בזה אבל הם כתובים ב-++C והם לא נגישים לזרים...
אבל אתה מעיר הערה חשובה שלא חשבתי עליו
יכול להיות (לכאורה) שיש דרך לטפל בזה בלי ליכנס למרתפים הסודיים של מייקרוסופט אלא על ידי שכלול המאקרו

חבר'ה אתם מוזמנים לתרום!

[yossiz]

@yossiz כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

יכול להיות (לכאורה) שיש דרך לטפל בזה בלי ליכנס למרתפים הסודיים של מייקרוסופט אלא על ידי שכלול המאקרו

Const whiteSpace As String = " " & vbTab & vbCrLf

Sub SelectToNextWhiteSpaceForward()
    If Selection.StartIsActive And Not Selection.Type = wdSelectionIP Then
        Selection.MoveStartWhile whiteSpace, wdForward
        Selection.MoveStartUntil whiteSpace, wdForward
        Selection.StartIsActive = True
    Else
        Selection.MoveEndWhile whiteSpace, wdForward
        Selection.MoveEndUntil whiteSpace, wdForward
    End If
End Sub

Sub SelectToNextWhiteSpaceBackward()
    If Selection.StartIsActive Or Selection.Type = wdSelectionIP Then
        Selection.MoveStartWhile whiteSpace, wdBackward
        Selection.MoveStartUntil whiteSpace, wdBackward
        Selection.StartIsActive = True
    Else
        Selection.MoveEndWhile whiteSpace, wdBackward
        Selection.MoveEndUntil whiteSpace, wdBackward
    End If
End Sub

יש עדיין באג קטנצ'יק, נראה אם תעלה על זה...

[מעלה ומוריד]

@yossiz כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

יש עדיין באג קטנצ'יק, נראה אם תעלה על זה...

הוא מדלג על מילה כשחוזרים אחורה...
נסבול את זה...

20230515_140143.mp4

[מעלה ומוריד]

בחומר שאני עורך כרגע אמר זקן המשגיחים, שלא כמידת הקב"ה מידת בשר ודם
אצל בני אדם יש גבול כמה אתה יכול לבקש טובות בלי להיות מנוול. אצל הקב"ה כמה שאתה יותר מנוול יותר טוב...

@yossiz והלכת בדרכיו...

[מעלה ומוריד]

@yossiz החלום שלי (נכון ל15/5/23 14:39) הוא להכין מאקרו כזה גם על Ctrl+Left וCtel+Right (הרי גם הם בעייתיים בדיוק באותה מידה)
ובמקביל להכין מאקרו שיגדיר את המאקרואים הללו שיפעלו לפי קיצורי המקשים המתאימים, כגון זה: https://tchumim.com/post/153061
ואז בלחיצת כפתור אני מאפשר לכלל העורכים בקבוצה הנ"ל לבצע את כלל ההגדרות הנצרכות להאי שופרא
כרגע אני מאמין שלא אצליח להסביר להם איך להתנהל עם המאקרו'ס...

[מעלה ומוריד]

@yossiz כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

יש עדיין באג קטנצ'יק, נראה אם תעלה על זה...

לכאורה אתה יכול להתגבר עליו אם הבחירה גם תתחיל מתו שאינו רווח

[מאקרו]

כתבתי על זה מאקרו בעבר בפורום אופיס
כאן

[yossiz]

@מעלה-ומוריד כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

החלום שלי (נכון ל15/5/23 14:39)

עכשיו 10:30 18/5/23, האם החלום כבר התגשם?

כי להכין עבור ctrl+right ו-ctrl+left הוא יותר קל

Const whiteSpace As String = " " & vbTab & vbCrLf

Sub MoveToNextWhiteSpaceForward()
    Selection.MoveWhile whiteSpace, wdForward
    Selection.MoveUntil whiteSpace, wdForward
End Sub

Sub MoveToNextWhiteSpaceBackward()
    Selection.MoveWhile whiteSpace, wdBackward
    Selection.MoveUntil whiteSpace, wdBackward
End Sub

[מעלה ומוריד]

תודה רבה איש יקר ועניו!
מתנגן לי משום מה 'חזו חזו'...

@yossiz כתב במאקרו לוורד לבחירת כל המילה כולל תווי פיסוק:

עכשיו 10:30 18/5/23, האם החלום כבר התגשם?

היינו כחולמים...