פונקציית vba & odbc

[ליבל]

@dovid תודה הרגשתי קצת שמשהו לא שווה כאן
אנסה להסביר שוב, במידה ועדיין לא מובן אשמח לענות
אני רוצה לחבר את הקובץ אקסס לטבלאות בשרת, כרגע האקסס מסונכרן ע"י גוף שלישי (odbc שזה קובץ מקומי במחשב). אני רוצה שבמקום שהנתוני חיבור הכול יתנהל בהיזשהו צורה ע"י האקסס \ VBA , וכפי שהבנתי הפונקציה שהבאתי כאן די מוגבלת כלומר עדיין לא הבנתי איך אני מקשר דרכו את הטבלאות

[OdedDvir]

@ליבל האם אתה יכול לכתוב קוד VBA?

[ליבל]

@OdedDvir עדיין לא כ"כ

[OdedDvir]

@ליבל התכוונתי האם אתה יכול להוסיף קוד לקובץ..

[ליבל]

@OdedDvir כן

[OdedDvir]

@ליבל יפה. עכשיו האם אתה יודע את מחרוזת החיבור ConnectionString?

[ליבל]

@OdedDvir כן, בדקתי וזה עובד.

[OdedDvir]

@ליבל אוקי, עכשיו האם נכון לעכשיו הטבלאות המקושרות מופיעות כבר ברשימת האובייקטים, או שצריך ליצור קישור חדש?

[ליבל]

@OdedDvir עדיין לא קישרתי את הכול

[ליבל]

@OdedDvir נתחיל קודם לעשות חדש

[OdedDvir]

@ליבל תפתח מודל חדש ותדביק את הקוד הבא (מאתר מייקרוסופט)

'//Name     :   AttachDSNLessTable
'//Purpose  :   Create a linked table to SQL Server without using a DSN
'//Parameters
'//     stLocalTableName: Name of the table that you are creating in the current database
'//     stRemoteTableName: Name of the table that you are linking to on the SQL Server database
'//     stServer: Name of the SQL Server that you are linking to
'//     stDatabase: Name of the SQL Server database that you are linking to
'//     stUsername: Name of the SQL Server user who can connect to SQL Server, leave blank to use a Trusted Connection
'//     stPassword: SQL Server user password
Function AttachDSNLessTable(stLocalTableName As String, stRemoteTableName As String, stServer As String, stDatabase As String, Optional stUsername As String, Optional stPassword As String)
    On Error GoTo AttachDSNLessTable_Err
    Dim td As TableDef
    Dim stConnect As String

For Each td In CurrentDb.TableDefs
        If td.Name = stLocalTableName Then
            CurrentDb.TableDefs.Delete stLocalTableName
        End If
    Next

If Len(stUsername) = 0 Then
        '//Use trusted authentication if stUsername is not supplied.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";Trusted_Connection=Yes"
    Else
        '//WARNING: This will save the username and the password with the linked table information.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";UID=" & stUsername & ";PWD=" & stPassword
    End If
    Set td = CurrentDb.CreateTableDef(stLocalTableName, dbAttachSavePWD, stRemoteTableName, stConnect)
    CurrentDb.TableDefs.Append td
    AttachDSNLessTable = True
    Exit Function

AttachDSNLessTable_Err:

AttachDSNLessTable = False
    MsgBox "AttachDSNLessTable encountered an unexpected error: " & Err.Description


End Function

הפונקציה הזו יוצרת קישור חדש לטבלה, ואם הטבלה כבר קיימת היא מוחקת את הקישור הקיים.
תחביר קריאה לפונקציה:

AttachDSNLessTable("dbo_myTable", "dbo.myTable", "SERVER_IP", "dbName", "user", "password")

[ליבל]

@OdedDvir בקריאה לפנקציה איזה פרמטרים הם 2 הראשונים ?

[OdedDvir]

@ליבל הראשון הוא השם המקומי שאתה רוצה לתת לטבלה. השני הוא השם האמיתי של הטבלה בdb

[ליבל]

@OdedDvir הגדרתי לחצן וקראתי לפונקציה ע"י call זה נכון ? (יש שגיאה)

[OdedDvir]

@ליבל מה השגיאה?

[ליבל]

פונקציה לא נמצאת

[OdedDvir]

@ליבל צריך לדבג ולראות אם הקוד כתוב נכון (שמתי לב שבאתר הוא מוסיף {1} בהתחלה של כמה שורות)
בעורך הVBA תבחר בתפריט Debug>Compile ותראה אם הוא נותן לך שגיאה

[ליבל]

@OdedDvir תודה רבה זה הצליח !!!

[OdedDvir]

@ליבל נהדר!