שליחת מייל דרך האקסס האם אפשרי???

[אוריי]

ניסיתי לחפש כל מיני קודים והתוצאה הייתה אחת מהשניים..
א. הקוד מחזיר שגיאה לדוגגמא אחד הקודים שפורסמו כאן

Public Sub SendGmail()
   'creating a CDO object
   Dim Mail As Object
   Set Mail = CreateObject("CDO.Message")
 
   'Enable SSL Authentication
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
   'Make SMTP authentication Enabled=true (1)
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
 
   'Set the SMTP server and port Details
   'Get these details from the Settings Page of your Gmail Account
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
   "smtp.gmail.com"
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
 
   'Set your credentials of your Gmail Account
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/sendusername") = _
   "*******@gmail.com"
   Mail.Configuration.Fields.Item _
   ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = _
   "******************"
   'Update the configuration fields
   Mail.Configuration.Fields.Update
 
   'Set All Email Properties
   With Mail
      .Subject = "היי, זה אני! הבאתי לך משהו!"
      .From = "*********@gmail.com"
      .To = "*********@gmail.com"
      .CC = ""
      .BCC = ""
      .textbody = "אתה יכול לפתוח את הדוח ולהציץ, אבל רק אם בא לך..."
      .AddAttachment ("c:\user.pdf") 'To attach Documents in mail
   End With
   'to send the mail
   Mail.Send
End Sub

ובשליחה הוא מחזיר שגיאה ראוי לציין שהנתונים והסיסמה שהזנתי היו תקינים
במייל עצמו אין שום איזכור

ב. בקשת אימות דו שלבי שמשום מה כל מה שניסיתי לעשות אימות כזה במייל או שנחסם המייל או שאין אפשרות לעשות את זה במחשב וכל מיני תירוצים למיניהם של גוגל
אשמח לשמוע תשובה ממי שהתנסה בזה
תודה רבה!

[Mordechai 0]

לא לגמרי הבנתי אותך, אבל מה שברור הוא ש־Gmail כבר מזמן חסמה את האפשרות לשלוח מיילים עם הסיסמה הרגילה, מטעמי אבטחה. כיום ניתן לשלוח מיילים רק באמצעות סיסמה ייעודית לאפליקציה (App Password), שניתן ליצור רק לאחר הפעלת אימות דו־שלבי (2FA) בחשבון.
אם אינך מעוניין להתעסק עם זה, אפשר להשתמש בשירות חיצוני כמו Brevo (לשעבר Sendinblue), שמאפשר לשלוח עד 300 מיילים חינם ביום.

[אוריי]

@Mordechai-0 כתב בשליחת מייל דרך האקסס האם אפשרי???:

רק באמצעות סיסמה ייעודית לאפליקציה (App Password), שניתן ליצור רק לאחר הפעלת אימות דו־שלבי (2FA) בחשבון.

זה מה שכתבתי שאני לא מצליח

כתב בשליחת מייל דרך האקסס האם אפשרי???:

ב. בקשת אימות דו שלבי שמשום מה כל מה שניסיתי לעשות אימות כזה במייל או שנחסם המייל או שאין אפשרות לעשות את זה במחשב וכל מיני תירוצים למיניהם של גוגל

אתה תוכל להסביר איך עושים סיסמה עם האפליקציה הייעודית הזו למשתמש כשר כמוני שאין לו אפליקציות....

[האדם החושב]

@אוריי כתב בשליחת מייל דרך האקסס האם אפשרי???:

אתה תוכל להסביר איך עושים סיסמה עם האפליקציה הייעודית הזו למשתמש כשר כמוני שאין לו אפליקציות....

זאת לא סיסמא עם אפליקציה אלא סיסמא לאפליקציה
https://support.google.com/accounts/answer/185833?hl=en#zippy=%2Cwhy-you-may-need-an-app-password

תוכל גם ליצור google script עם פריסה ולשלוח אליו את ההודעה והוא ישלח אותה במייל.

[Mordechai 0]

@אוריי כתב בשליחת מייל דרך האקסס האם אפשרי???:

אתה תוכל להסביר איך עושים סיסמה עם האפליקציה הייעודית הזו למשתמש כשר כמוני שאין לו אפליקציות....

זה בעייתי לפי מה שאני ניסיתי חייבים SMS בשביל האימות דו שלבי
יצירת הסיסמה זה ממש פשוט אבל בחשבון חייב להיות מופעל האימות דו שלבי

[אוריי]

@Mordechai-0 יש לי sms
תוכל לעזור לי בפרטי?

[Mordechai 0]

בשמחה
8406695@gmail.com

[יהודי טוב]

אני עשיתי בכמה פרויקטים סקריפט פשוט בגוגל סקריפט,

שמקבל כתובת שולח, HTML של תוכן, ושולח מייל.

זה משהו שחסך לי את ההתעסקות הזו.

[חגי]

@Mordechai-0 כתב בשליחת מייל דרך האקסס האם אפשרי???:

זה בעייתי לפי מה שאני ניסיתי חייבים SMS בשביל האימות דו שלבי

אני חושב שאפשר גם באפליקציית אימות (שבמקרה שלי היא תוסף לדפדפן, שזה קצת הורס את הקטע של האימות הדו שלבי, אבל במקרה הזה שרק צריך את הסיסמאות לאפליקציות זה אמור להיות בסדר)

[אוריי]

למעשה ב vba לא ניתן לשלוח דרך שום פורט בgpt הוא נתן לי 2 פורטים ושניהם חסומים.

@יהודי-טוב כתב בשליחת מייל דרך האקסס האם אפשרי???:

אני עשיתי בכמה פרויקטים סקריפט פשוט בגוגל סקריפט,

שמקבל כתובת שולח, HTML של תוכן, ושולח מייל.

תוכל לפרט יותר איך עושים את זה השלבים וכו'...
או לתת קודים שעושים את העבודה?

[יהודי טוב]

1 - תיכנס לכאן https://script.google.com/u/0/home?pli=1
2 - פרויקט חדש.
3 - תדביק שם את הקוד הבא:

function doPost(e) {
  try {
    const data = JSON.parse(e.postData.contents);
    const { to, replyTo, subject, body, token } = data;
    if (!to || !token || token != "123456789") throw new Error("error");

    MailApp.sendEmail({
      to: to,
      name: 'שם השולח שאתה רוצה שיופיע',
      htmlBody: body,
      subject: subject || '',
      replyTo: replyTo || null
    });

    return ContentService.createTextOutput('');
  } catch (err) {
    return ContentService.createTextOutput("error")
  }
}

ואז אתה פורס
לפריסה->פריסה חדשה ->גלגל שיניים בחירת סוג -> אפלקציית אינטרנט.
לבצע בתור = "עצמי".
למי יש גישה = "כולם"
לפריסה.

ואתה צריך לאשר את ההרשאות.

ובסיום אתה מקבל כתובת URL.
שאתה פונה אליה בפוסט ומעביר את הפרמטרים כפי שהם כתובים בקוד.
שים לב לטוקן שיש שם.

[avi rz]

רגע,
זה נראה שהשאלה הייתה על אקסל על ה desktop - של מייקרוסופט.
וההצעה הייתה ל googleSheets + appScript
אגב, אני גם משתמש בזה כבר המון זמן חוסך הרבה, עבור שליחת חשבוניות וכו'.
לגבי השאלה:
אם אתה משתמש באאוטלוק -אז יש אפשרות להוסיף מיילים לשליחה לאאוטלוק וזה גם אמור לעבוד חלק.
או באמת לעבור ל GoogleSheets
בהצלחה.

[צדיק תמים]

@avi-rz כתב בשליחת מייל דרך האקסס האם אפשרי???:

זה נראה שהשאלה הייתה על אקסל על ה desktop - של מייקרוסופט.
וההצעה הייתה ל googleSheets + appScript

לא
גוגל סקריפט כאן משמש כ"שרת בקאנד" שאפשר לשלוח אליו בקשה מהאקסל המקומי והוא שולח מייל

[אוריי]

@יהודי-טוב
תודה רבה אין מילים עובד מעולה....
וישר כח עצום ל @Mordechai-0 על העזרה הענקית בפרטי

[אוריי]

@יהודי-טוב האם יש אפשרות לדעת אם באמת נשלח המייל דרך הסקריפט.
כלומר מה אתה עושה אם יש שגיאה בסקריפט?
אצלי למשל הוא מריץ את הvba גם אם אין אינטרנט והוא לא נתקל בשום שגיאה.... איך אני יכול לבדוק את זה?

[יהודי טוב]

בעיקרון אם חוזר לך "error" זה אומר שהוא נתקל בשגיאה.

אבל הבעיה אצלך היא בשלב לפני..

הבקשה לא מגיעה לשם בכלל.

אתה צריך אצלך בקוד לבדוק שאם לא חוזר תגובה (כרגע חוזר סטרינג ריק - אתה יכול לכתוב שם משהו כמו OK) אז תתריע למשתמש.

[Mordechai 0]

@אוריי כתב בשליחת מייל דרך האקסס האם אפשרי???:

@יהודי-טוב האם יש אפשרות לדעת אם באמת נשלח המייל דרך הסקריפט.
כלומר מה אתה עושה אם יש שגיאה בסקריפט?
אצלי למשל הוא מריץ את הvba גם אם אין אינטרנט והוא לא נתקל בשום שגיאה.... איך אני יכול לבדוק את זה?

שים לב הקוד שנתתי לך בולע שגיאות

[אוריי]

@Mordechai-0
הנה הקוד שנתת לי בתור פונקציה

Public Function email() As String

    Dim toAddress As String
    Dim subjectText As String
    Dim bodyHtml As String
    Dim token As String
    Dim url As String
     
    toAddress = "123456789@gmail.com"
    subjectText = "hi"
    bodyHtml = "hi"
    token = "123456789"
    url = "https://script.google.com/macros/s/"
     
    On Error Resume Next
     
    With CreateObject("MSXML2.XMLHTTP")
        .Open "POST", url, False
        .setRequestHeader "Content-Type", "application/json"
        .Send "{""to"":""" & toAddress & """,""subject"":""" & subjectText & """,""body"":""" & bodyHtml & """,""token"":""" & token & """}"
        .abort
    End With
   email = "???"
   
    On Error GoTo 0

End Function

איך אני יכול לקבל את ה error (התשובה מהסקריפט) בחזרה?

[יהודי טוב]

@אוריי כתב בשליחת מייל דרך האקסס האם אפשרי???:

איך אני יכול לקבל את ה error (התשובה מהסקריפט) בחזרה?

הכי פשוט לשאול את אחד הAIים.

[יהודי טוב]

@אוריי שאלתי בשבילך

ובכל אופן תנסה את הקוד הזה:

Public Function email() As String
    Dim toAddress As String
    Dim subjectText As String
    Dim bodyHtml As String
    Dim token As String
    Dim url As String
    Dim http As Object
    
    ' פרטי ההודעה
    toAddress = "123456789@gmail.com"
    subjectText = "hi"
    bodyHtml = "hi"
    token = "123456789"
    url = "https://script.google.com/macros/s/"
    
    On Error GoTo ErrHandler
    
    ' יצירת אובייקט HTTP
    Set http = CreateObject("MSXML2.XMLHTTP")
    
    ' פתיחת הבקשה
    http.Open "POST", url, False
    http.setRequestHeader "Content-Type", "application/json"
    
    ' שליחת הנתונים
    http.Send "{""to"":""" & toAddress & """,""subject"":""" & subjectText & """,""body"":""" & bodyHtml & """,""token"":""" & token & """}"
    
    ' בדיקת קוד סטטוס
    If http.Status <> 200 Then
        Err.Raise vbObjectError + 1, "email", "השרת החזיר קוד שגיאה: " & http.Status
    End If
    
    ' החזרת תגובת השרת
    email = http.responseText
    Exit Function
    
ErrHandler:
    email = "שגיאה: " & Err.Description
End Function