איך אני יכול לפצל קובץ וורד גדול לפי מקטעים

[אוריי]

יש לי קובץ וורד שהוא כבד וקשה לעבוד עליו.
הקובץ מחולק למקטעים כך שאני רוצה לפצל אותו לפי מקטעים שכל מקטע יהיה בקובץ נפרד.
חיפשתי בגוגל אבל לא מצאתי משהוא בכיון ראיתי פיצול לפי מילה ראשונה ואחרונה אבל יש לי מלא קבצים ומלא מקטעים בכל קובץ כך שהעבודה ענקית.
והשם של הקובץ יהיה השם שלו + מספר המקטע הקיים

[OdedDvir]

@אוריי תדביק את הקוד הבא במודול:

Public Sub SplitActiveDocumentBySection()
    Dim outputDoc As Document
    Dim sectionCount As Integer
    Dim currentSection As Section
    Dim baseFileName As String
    
    sectionCount = ActiveDocument.Sections.Count
    If MsgBox("Would you like to split this document into " & sectionCount & " sections?", vbYesNo) <> vbYes Then Exit Sub

    baseFileName = CreateObject("Scripting.FileSystemObject").GetBaseName(ActiveDocument.Name)
    For Each currentSection In ActiveDocument.Sections
        Application.StatusBar = "Saving section " & currentSection.Index & " of " & sectionCount & "..."
        currentSection.Range.Copy
        Set outputDoc = Documents.Add(Visible:=False)
        outputDoc.Range.Paste
        outputDoc.SaveAs ActiveDocument.Path & "\" & baseFileName & "_Section_" & Right$("000" & currentSection.Index, 4) & ".docx"
        outputDoc.Close
    Next currentSection
    Application.StatusBar = "All Done!"
    Set outputDoc = Nothing
End Sub

[אוריי]

@OdedDvir תודה ענקית
איך אני מקבל את השם של הקובץ ללא הסיומת?

[OdedDvir]

@אוריי אמר באיך אני יכול לפצל קובץ וורד גדול לפי מקטעים:

איך אני מקבל את השם של הקובץ ללא הסיומת?

נראה לי שהבנתי לאן אתה חותר, הוספתי את השינוי הזה במקור.

[אוריי]

@OdedDvir
בהתחלה עבד טוב כעת הוא מחזיר שגיאה
עריכה: השגיאה הזו מעוררת לפי המצב רוח. לפעמים הקוד עובד טוב ולפעמים.....

וכן הוא לא מחזיר לי את שם הקובץ

[yossiz]

נראה מכאן שאפשר מצב שההעתקה לא נגמרה, וצריך לחכות טיפה לפני הדבקה (או להעביר את התוכן ישירות - לא באמצעות לוח ההדבקה)

[אוריי]

@yossiz אמר באיך אני יכול לפצל קובץ וורד גדול לפי מקטעים:

(או להעביר את התוכן ישירות - לא באמצעות לוח ההדבקה)

איך??
גזירה והדבקה?!! גם זה דרך הלוח??!!

[אוריי]

@yossiz
אכן מבדיקה שלי אם אני מפעיל בריצה איטית על השורה הזו וממתין כמה שניות הקוד עובר בהצלחה ללא שגיאה
זאת אומרת שאם אני יכתוב פקודה שימתין כמה שניות זה יעבוד מעולה.
עריכה: הוספתי את הפקודה הבאה ועובד מעולה @yossiz @OdedDvir הרבה תודה

Dim tmpStart
tmpStart = Timer
Do
    DoEvents
Loop While (tmpStart + 3) > Timer