תחומים - פורום חרדי מקצועי

@one1010
אתה צריך ליצור או לשכתב שאילתה ייעודית לחיפוש הנוכחי.
לייצא אותה לאקסל
ולשלוח את האקסל במייל.

ככה אתה משכתב שאילתה קיימת:

CurrentDb.QueryDefs("שםהשאילתה").SQL = "select * from [שם הטבלה] " & " where " & תוצאותהחיפוש

'תוצאותהחיפוש' תלוי איך עשית את החיפוש, אבל בהמשך לפוסט הזה,
זה תוצאות החיפוש
"[" & Me.cobField & "] like " & Chr(34) & "" & Me.txtFind & "" & Chr(34)

וככה אתה מייצא את השאילתה לאקסל:

    DoCmd.TransferSpreadsheet acExport, , "שםהשאילתה", strPath , False

למשתנה strPath צריך לתת נתיב מלא ושם הקובץ לפני הפעלת השורה.
זה דוגמא לאיך לתת לו נתיב ושם עם התאריך הנוכחי

    Dim strPath As String
    strPath = CurrentProject.Path & "\" & "שםכלשהו" & Format(Date, "dd-mm-yyyy")  & ".xls"

ואז לשלוח את הנתיב הזה למייל.

תוכל למחוק את הקובץ מהמחשב אחרי השליחה ככה

If Len(dir(strPath)) > 0 Then Kill strPath

אתה צריך למחוק את כל המקומות שכתוב fsubForm

    If Len(Me.txtFind) > 0 Then
        Me.fsubForm.Form.Filter = "[" & Me.cobField & "] like " & Chr(34) & "*" & Me.txtFind & "*" & Chr(34)
        Me.fsubForm.Form.FilterOn = True
    Else
        Me.fsubForm.Form.Filter = ""
        Me.fsubForm.Form.FilterOn = False
    End if

הקוד הזה עושה סינון לטופס משנה.

@ג-ינג-י @OdedDvir
אני משתמש עם הקוד הזה. בכל חיפושי הטפסים, נראה לי הרבה יותר קל.
בעת יציאה מתיבת החיפוש שכאן הוא txtFind הוא מבצע את החיפוש.
(אפשר להכניס אותו תוך כדי כתיבה ב'בעת שינוי', אבל בהרבה נתונים הוא ממש מאיט את העבודה)
והטופס משנה אצלי נקרא fsubForm
במקרה שאין טופס משנה, רק רוצים חיפוש בטופס הנוכחי, צריך להוריד את הfsubForm בכל המופעים

    On Error GoTo err
    
        Dim ctl As Control
        Dim strFilter As String
    
        If Me.fsubForm.SourceObject = "" Then Exit Sub
    
        If Len(Me.txtFind.text) < 1 Then
            Me.fsubForm.Form.FilterOn = False
            Exit Sub
        Else
        End If
    
        For Each ctl In Me.fsubForm.Form.Controls    'Me.Controls
            If ctl.ControlType = acTextBox Or ctl.ControlType = acComboBox Then 'רק פקדי טקסט
                If Left(ctl.ControlSource, 1) <> "=" Then 'דלג על תיבות טקסט מחושבים
                    strFilter = strFilter & "[" & ctl.ControlSource & "] Like " & Chr(34) & "*" & txtFind.text & "*" & Chr(34) & " OR "
                End If
            End If
        Next
        strFilter = Left(strFilter, Len(strFilter) - 4)
        Me.fsubForm.Form.Filter = strFilter
        Me.fsubForm.Form.FilterOn = True
        Exit Sub
    

    err:
        Me.fsubForm.Form.Filter = ""
        Me.fsubForm.Form.FilterOn = False

@מערכת
ביקשו לראות איך ה'טבלה' נראית. טבלה היא מקור נתונים לא פיווט.
אם אתה רוצה להיעזר, תן דוגמא של 2 הדברים,
1 הנתונים כפי שהם מופיעים.
2. איך אתה רוצה את התוצאה.
תוכל כמובן להשתמש עם נתוני דמה.

ואז ישמחו לעזור לך.

@evi952 כתב בWorkspace קבלת מיילים לדואר:

@מלא תודה לא לזה התכוונתי
יש לי מייל חשבון עסקי עם דומיין שרכשתי ואני צריך שם להגדיר את ההגדרות ושם זה קצת מסובך יש הרבה אפשרויות

כתבתי בתגובה הראשונה שלי, שאם הכוונה שלך זה בהגדרות של ג'ימייל.
אז התמונה שצירפתי לך, זה מהג'ימייל של חשבון workSpace עם דומיין פרטי.

@evi952
גלגל שיניים > הצגת כל ההגדרות > חשבונות

@evi952
מה שאני כתבתי לך זה בג'ימייל של חשבון וורקספייס

@evi952
לא הגדרתי אף פעם בפאוורלינק שליחת מיילים.
אם ההגדרה היא בגוגל אז כמו בכל חשבון ג'ימייל
יש לך אפשרות שליחת אימייל בשם
גלגל שיניים > הצג את כל ההגדרות > חשבונות
אם לזה התכוונת

@evi952
את ההגדרות האלה ביצעת?
https://www.powerlink.co.il/support/kb/הגדרות מערכת/הגדרות משתמש/הגדרת Team Inbox

@ארי
מה היתה התקלה? סתם בשביל הסקרנות, ואולי גם ללימוד....

@ארי כתב בהורדת קבלות מאתר איזיקאונט (ezcount):

דוגמא של קישור

https://files.ezcount.co.il/front/documents/get/00e96269-f39e-407a-8d64-f8***9a0

@ארי
אני מוריד איתו מסמכים לאורך זמן ולא ידוע לי על שום בעיה איתו.
הורדתי איתו מאות ואולי אלפי מסמכים

בדקת את הקישור של הקבצים האלה שבגישה ישירה הם נותנים לך מסמך תקין?
אולי זה בעיה בקישור

@ארי
יש לך את הקישור לPDF שהם נותנים בעת יצירה?

אם כן
אני מוריד קבלות עם הקוד הזה
זה ההצרה והפונקציה

Option Compare Database
Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal _
    szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long


Function DownloadFile(URL As String, LocalFilename As String) As Boolean
    Dim lngRetVal As Long
    lngRetVal = URLDownloadToFile(0, URL, LocalFilename, 0, 0)
    If lngRetVal = 0 Then DownloadFile = True
End Function

וככה אני מוריד

Private Sub txtOrginalFileLink_DblClick(Cancel As Integer)
    Dim strPDFLink As String
    Dim strPDFFile As String
    Dim Result As Boolean
    strPDFLink = Me.txtOrginalFileLink
    strPDFFile = CurrentProject.Path & "\חשבוניות\" &  Me.מס_חשבונית & ".pdf"
    Result = DownloadFile(strPDFLink, strPDFFile)
    MsgBox Result

End Sub

@laswater
מה הצורך שלך באחסון,

אם כדי שיוכלו לעבוד עליו כמה אנשים ביחד ברשת חיצונית,
אז אין אפשרות כזאת כלל וכלל.

• כדי שיוכלו לעבוד כמה אנשים מרחוק, עושים שליטה מרחוק על מחשב-שרת אחד. וכולם מתחברים אליו.
• יש גם אפשרות להעביר את מסד הנתונים לשרת SQL ולחבר אליו את האקסס, אבל הוא עובד נורא לאט, וכלל לא מומלץ לעבוד ככה בעבודה שוטפת.

אם הצורך שיהיה גיבוי של החומר כל הזמן,
אז כל המסנכרנים של תקיות במחשב
כדוגמת דרופבוקס, גוגל דרייב, וואן דרייב וכו' שווים.

@בעל-כישרון כתב בתכנון אקסס לכמה משתמשים:

וחסימה של F11

אתה מייצר מאקרו בשם AutoKeys
ובתוכו אתה מוסיף מאקרו משנה
בשורה הראשונה תכתוב {F11}
ובשורה השניה בהוסף פעולה תכניס Beep

---

@בעל-כישרון כתב בתכנון אקסס לכמה משתמשים:

כניסה עם שיפט

צור מודול חדש והוסף בו את שתי הפונקציות הבאות. (אף פעם לא השתמשתי עם זה, מקווה שבאמת עובד)

Function ap_DisableShift()
'This function disable the shift at startup. This action causes
'the Autoexec macro and Startup properties to always be executed.

On Error GoTo errDisableShift

Dim db As DAO.Database
Dim prop as DAO.Property
Const conPropNotFound = 3270

Set db = CurrentDb()

'This next line disables the shift key on startup.
db.Properties("AllowByPassKey") = False

'The function is successful.
Exit Function

errDisableShift:
'The first part of this error routine creates the "AllowByPassKey
'property if it does not exist.
If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, False)
db.Properties.Append prop
Resume Next
Else
MsgBox "Function 'ap_DisableShift' did not complete successfully."
Exit Function
End If
End Function

Function ap_EnableShift()
'This function enables the SHIFT key at startup. This action causes
'the Autoexec macro and the Startup properties to be bypassed
'if the user holds down the SHIFT key when the user opens the database.

On Error GoTo errEnableShift

Dim db as DAO.Database
Dim prop as DAO.Property
Const conPropNotFound = 3270

Set db = CurrentDb()

'This next line of code disables the SHIFT key on startup.
db.Properties("AllowByPassKey") = True

'function successful
Exit Function

errEnableShift:
'The first part of this error routine creates the "AllowByPassKey
'property if it does not exist.
If Err = conPropNotFound Then
Set prop = db.CreateProperty("AllowByPassKey", _
dbBoolean, True)
db.Properties.Append prop
Resume Next
Else
MsgBox "Function 'ap_DisableShift' did not complete successfully."
Exit Function
End If

End Function

בעורך Visual Basic, לחץ על חלון מיידי בתפריט תצוגה.
אם ברצונך להשבית את מקש SHIFT, הקלד ap_DisableShift בחלון המיידי ולאחר מכן הקש ENTER. אם ברצונך להפעיל את מקש Shift, הקלד ap_EnableShift בחלון המיידי ולאחר מכן הקש ENTER.
-עד כאן העתקה שאיני יודע למי הקרדיט (כנראה לאי מי מפרוג... שהמציא לי איזה קישור) כי זה שמור לי משנים קדמוניות במחשב.

@laswater
הנוהג לעשות בקבצי אקסס שמחלקים את הקובץ ל2.
הנתונים. והפרונט.
כשעושים עדכון בפרונט, אין צורך לגעת בקובץ הנתונים.
אם זה לא מחולק כפי שנשמע מהשאלה,
אז קודם כל תעשה את זה, [א. כי ככה הנתונים יותר שמורים. ב. כי בעדכונים הבאים לא תצטרך לעבוד קשה]
(תכנס באקסס ל'כלי מסד נתונים' > במקטע העברת נתונים, 'מסד נתונים של אקסס')
ואז תוכל לעדכן את התוכנה בקלות.

אם אתה צריך גם להוסיף עמודות ו/או טבלאות בנתונים,
אז תצטרך משהו לעדכן את זה.
יש לזה כמה דרכים,
תמקד איפה אתה נתקל בבעיה והאנשים פה בטח יעזרו לך.

@סקרן-0
אכן. 160
(32 כנראה רווח פשוט או דומה לו, בהעתקה לוורד הוא לא מגיע בכלל)
תודה רבה
(תרגום גוגל נתן לי Hard profit במקום Gain, שלא החזיר את הנושא)

@Y-Excel-Access כתב באיך מזהים בVBA תו 'רווח קשיח':

אני לא יודע מה הכוונה לרווח 'קשיח'.

רווח קשיח הוא תו שקיים בוורד ובמעבדי טקסטים שגורם ל2 מילים להישאר באותה שורה.

@Y-Excel-Access כתב באיך מזהים בVBA תו 'רווח קשיח':

וכן, בעיקרון אפשר להחליף כל תו עם Replace ב VBA ולכאורה אף בקוד פקד באמצעות בונה הביטויים

זה מה שאני מחפש, את הביטוי שימצא את התו הזה.

@Y-Excel-Access כתב באיך מזהים בVBA תו 'רווח קשיח':

כתוב באקסל..

אני מחפש איזה מספר אני צריך להכניס לכאן.

אני מייצר קבצי מס"ב באקסס, והתו 'רווח קשיח' מחזיר שגיאה ממס"ב בלי להודיע את סיבת התקלה.
ישבתי עם מס"ב חצי שעה בטלפון ולא הצליחו לאתר את הבעיה..

אני רוצה להעיף את התו הזה בצורה גורפת בטבלה של קבצי מס"ב
איך מזהים אותו בACII (Chr זה ACII??)
או כל צורה שהיא?