חיפוש והחלפה בוורד מתוך קובץ אקסל

[אוריי]

יש לי מלא חיפושים והחלפות בוורד (קרוב ל400) שכתבתי אותם בקובץ אקסל כך
עמודה A מה לחפש, עמודה B במה להחליף, עמודה C תווים כלליים.

יש לי כרגע קוד שפותח לי את הקובץ אקסל

Dim ExcelDoc As Object

Set ExcelDoc = CreateObject("Excel.Application")
ExcelDoc.Visible = True
ExcelDoc.Workbooks.Open "F:\ערוך\החלפות.xlsx"

Set ExcelDoc = Nothing

מה שחסר לי זה לולאה שתרוץ שורה שורה ותחזיר לי את 3 הערכים שבשורה.

[pcinfogmach]

סליחה שאני שואל יש לך גיש לבינה מלאכותית?

[אוריי]

@pcinfogmach כתב בחיפוש והחלפה בוורד מתוך קובץ אקסל:

סליחה שאני שואל יש לך גיש לבינה מלאכותית?

לא

[אוריי]

ישר כח ל@pcinfogmach על העזרה באישי הנה הקוד שיצא לי

Sub גיש_לקובץ_Excel()

    Dim xlApp As Object
    Dim xlWorkbook As Object
    Dim xlWorksheet As Object
    ActiveDocument.TrackRevisions = True
    ' פתח אפליקציה של Excel
    Set xlApp = CreateObject("Excel.Application")
    
    ' פתח את הקובץ Excel
    Set xlWorkbook = xlApp.Workbooks.Open("F:\ערוך\החלפות.xlsx")
    xlApp.Visible = True
    ' בחר את גליון העבודה שבו נמצאים הנתונים
    Set xlWorksheet = xlWorkbook.Sheets("גיליון4")

    ' קרוא את הנתונים מתאים בגליון העבודה
    Dim data1 As String
    Dim data2 As String
    Dim data3 As Boolean
    
    Dim i
    i = 2
    
    Do While xlWorksheet.Cells(i, 1).Value <> ""
    data1 = xlWorksheet.Cells(i, 1).Value '  קורא את  A
    data2 = xlWorksheet.Cells(i, 2).Value '  קורא את B
    data3 = xlWorksheet.Cells(i, 3).Value ' קורא את C
    
    exchange data1, data2, data3
    
    i = i + 1
    Loop
    
    ' סגור את הקובץ Excel
    xlWorkbook.Close
    Set xlWorkbook = Nothing
    
    ' סגור את אפליקצית Excel
    xlApp.Quit
    Set xlApp = Nothing
End Sub



Public Function exchange(d1 As String, d2 As String, d3 As Boolean)
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = d1
        .Replacement.Text = d2
        .Forward = True
        .Wrap = wdFindContinue
        .MatchWildcards = d3
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Function

[האדם החושב]

@אוריי
תירגמתי בעבר תוסף לוורד שעושה בדיוק את הפעולה הזו
https://mitmachim.top/post/661445
ושילבתי אותו בתוך התוסף שלי לוורד
אולי ניתן יהיה להתאים את קוד המאקרו שבתוסף ההוא ליוז-קייס הספציפי שלך